El bucle WHILE en SQL

El bucle WHILE en T-SQL es una estructura de control que permite repetir un bloque de código mientras se cumpla una condición específica.

En la mayoría de lenguajes de programación (Python, C#, Java), los bucles son el pan de cada día. Los usamos para recorrer listas, arrays o procesar archivos.

En SQL Server, la historia es un poco diferente. SQL es un lenguaje orientado a conjuntos. Está diseñado para procesar 1 millón de filas de golpe con una sola instrucción UPDATE o SELECT.

Sin embargo, a veces no queda más remedio que ensuciarse las manos y procesar algo paso a paso. Para estos casos, T-SQL nos ofrece un único tipo de bucle, el bucle WHILE.

Sintaxis Básica

La estructura es muy sencilla: Mientras la condición sea verdadera, el código dentro del bloque BEGIN...END se repetirá.

WHILE Condición
BEGIN
    -- Código a repetir
    -- ¡IMPORTANTE! Algo debe cambiar aquí para que la condición sea falsa eventualmente
END

Ejemplo básico

Imaginemos que queremos imprimir los números del 1 al 5 utilizando un bucle WHILE. El código sería el siguiente:

DECLARE @contador INT = 1;

WHILE @contador <= 5
BEGIN
    PRINT 'Contador: ' + CAST(@contador AS VARCHAR);
    SET @contador = @contador + 1;
END

Controlando el flujo: BREAK y CONTINUE

A veces necesitamos alterar el comportamiento normal del bucle. Para eso tenemos dos comandos:

DECLARE @k INT = 0;

WHILE @k < 10
BEGIN
    SET @k = @k + 1;

    -- Si es par (el resto de dividir por 2 es 0), lo saltamos
    IF @k % 2 = 0 
        CONTINUE; -- Vuelve arriba, no ejecuta el PRINT
        
    PRINT 'Número impar: ' + CAST(@k AS VARCHAR);
END

DECLARE @i INT = 1;

WHILE @i <= 100
BEGIN
    PRINT @i;
    
    IF @i = 5
    BEGIN
        PRINT 'Encontrado el 5. ¡Nos vamos!';
        BREAK; -- Rompe el bucle aquí mismo
    END

    SET @i = @i + 1;
END

La gran advertencia: RBAR (Row By Agonizing Row)

En el mundo de SQL Server, existe un término despectivo para el uso excesivo de bucles: RBAR (Row By Agonizing Row).

Imagina que quieres subir el sueldo un 10% a todos los empleados (ejemplo sencillo, pero sirve para demostrar una cosa).

UPDATE Empleados SET Salario = Salario * 1.10;
-- Tiempo: 0.05 segundos para 10.000 filas.

-- Pseudocódigo
WHILE (queden filas)
BEGIN
   UPDATE Empleados SET Salario ... WHERE ID = @IDActual;
END
-- Tiempo: 15 segundos para 10.000 filas.